# Kapitel 1: 
# Die gezupfte Saite
#  2017  Friedrich U. Mathiak, 
# mathiak@mechanik-info.de
# 
# 
> restart:with(LinearAlgebra): with(plots):  with(plottools):
> Proc_Calc_03:=proc(Daten::list)
> #----------------------------------------------------------------------------
> #Eingabe:
> #   Daten[1]: l: Lnge der Saite in [m]
> #   Daten[2]: M: Masse  der Saite in [kg]
> #   Daten[3]  S: Vorspannkraft in [N]
> #   Daten[4]: a: Zupfstelle in [m]
> #   Daten[5]: h: Anfangsauslenkung der Saite an der Zupfstelle x=a in [m]
> #   Daten[6]: N: Anzahl der zur bercksichtigen Reihenglieder
> #Ausgabe:
> #             y: Bewegungsgleichung  der Saite
> #             v: Geschwindigkeit der Saite
> #            AN: Animation des Bewegungsvorgangs  
> #----------------------------------------------------------------------------
> local l,M,S,a,h,mu,c,alpha,eta,T1,n,nP;
> global y,v,AN;
> description "Die gezupfte Saite";
> l :=Daten[1]; M:= Daten[2]; S:= Daten[3]; a:= Daten[4]; h:=Daten[5];
> mu:=M/l; c:=sqrt(S/mu); alpha:=a/l; eta:=h/l;
> T1:=2*l/c;
> y :=0:
> for n to Daten[6] do
>   nP:=n*Pi;
>   y :=y + 1/n^2*sin(nP*alpha)*sin(nP*xi)*cos(2*nP*tau);
> end do;
> y:=2*eta*l/(alpha*(1-alpha)*Pi^2)*y;
> v:=1/T1*diff(y,tau);
> #Animation des Bewegungsvorgangs
> AN:=plots[animate](y, xi=0..1, tau=0..1, axes=framed, frames=150,color=blue,thickness=3,gridlines=true,axes=boxed,title = "\nDie gezupfte Saite\n", titlefont = ["ARIAL", 15], labels = ["Bezogene Saitenlnge  = x/l", "Auslenkung in [m]"], labeldirections = ["horizontal", "vertical"], labelfont = ["HELVETICA", 10], axesfont = ["HELVETICA", "ROMAN", 8]);
> end proc:
> 
;
# Beispiel 1-2:
# 
# Eine Gitarrensaite der Masse M und der Lnge  ist mit der Kraft S vorgespannt. Zum Zeitpunkt t = 0 wird sie an der Stelle x = a um das kleine Ma h ausgelenkt (angezupft) und sodann, ohne Anfangsgeschwindigkeit, sich selbst berlassen. Es ist die Auslenkung w(x, t) zu bestimmen. Animieren Sie mit Maple diesen Bewegungsvorgang. Mit welcher Spannkraft S muss die Saite vorgespannt werden, damit sie in der 1. Eigenschwingung (Grundschwingung) mit der Frequenz f = 264 Hz (in der C-Dur Tonleiter das kleine c) schwingt?
> l:=0.65;               #Saitenlnge in [m]
;
> M:= 0.4594579258e-3;   #Gesamtmasse der Saite in [kg] 
;
> mu:=M/l;               #Massenbelegung in [kg/m]
;
> S:=55.;                #Vorspannkraft in [N]
;
> a:=0.13;               #Zupfstelle in [m]
;
> h:=0.01;               #Anfangsauslenkung der Saite an der Zupfstelle x = a in [m]
;
> N:=30;                 #Anzahl der zu bercksichtigenden Reihenglieder
;
> sys:=[l,M,S,a,h,N];
> Proc_Calc_03(sys):
# Wir animieren den Bewegungsvorgang
> AN;
# 
